;
; Clean way of updating IAL upon you joining a channel
; or issuing the command '/ialupd [channel]'.
;
; Designed to work with in a multi-server environment
;
; Written by Bekar (20030117)
;
ALIAS -l lscript {
  if ($prop == name) {
    return 6,0[2,0A-Thingy6,0]
  }
}
ON *:START: {
  unset %ialupd.*
}
ON *:EXIT: {
  unset %ialupd.*
}
ON *:DISCONNECT: {
  unset %ialupd. $+ $cid
}
ON *:JOIN:#: {
  if ($nick == $me) {
    %ialupd. [ $+ [ $cid ] ] = $addtok($eval($+(%, ialupd., $cid), 2), #, 44)
  }
}
RAW 353:*: {
  if ($istok($eval($+(%, ialupd., $cid), 2), $3, 44)) {
    halt
  }
}
RAW 366:*: {
  if ($istok($eval($+(%, ialupd., $cid), 2), $2, 44)) {
    if ($nick($2,0) < 500) {
      .quote MODE $2 b $+ $lf $+ WHO $2
      } | else {
      .timer 1 $calc($numtok($eval($+(%, ialupd., $cid), 2), 44) * 8) .quote MODE $2 b
      .timer 1 $calc($numtok($eval($+(%, ialupd., $cid), 2), 44) * 15) .quote WHO $2
    }
    halt
  }
}
RAW 352:*: {
  if ($istok($eval($+(%, ialupd., $cid), 2), $2, 44)) {
    halt
  }
}
RAW 315:*: {
  if ($istok($eval($+(%, ialupd., $cid), 2), $2, 44)) {
    if ($numtok($eval($+(%, ialupd., $cid), 2), 44) > 1) {
      %ialupd. [ $+ [ $cid ] ] = $remtok($eval($+(%, ialupd., $cid), 2), $2, 1, 44)
      } | else {
      unset %ialupd. $+ $cid
    }
    echo -st $lscript($script).name  $+ $color(info2 text) IALUPD:- IAL Update for $2 completed.
  }
  halt
}
RAW 367:*: {
  if ($istok($eval($+(%, ialupd., $cid), 2), $2, 44)) {
    halt
  }
}
RAW 368:*: {
  if ($istok($eval($+(%, ialupd., $cid), 2), $2, 44)) {
    halt
  }
}
ALIAS ialupd {
  if ($1) {
    if ($me ison $1) {
      %ialupd. [ $+ [ $cid ] ] = $addtok($eval($+(%, ialupd., $cid), 2), $1, 44)
      .quote MODE $1 b $+ $lf $+ WHO $1
    }
    else {
      echo -st $lscript($script).name You are not in the channel $1, so cannot update your IAL
    }
  }
  else {
    if ($active ischan) {
      %ialupd. [ $+ [ $cid ] ] = $addtok($eval($+(%, ialupd., $cid), 2), #, 44)
      .quote MODE # b $+ $lf $+ WHO #
    }
    else {
      echo -st $lscript($script).name You must specify a channel, or have a channel as the active window!
    }
  }
}