ON 1:LOAD: {
  if ($exists($scriptdirDCCINFO) == $false) { mkdir $scriptdir $+ DCCINFO }
  alias dccinfodir return $scriptdir $+ DCCINFO\
}

ON *:FILERCVD:*: {
  CreateWindow
  aline -h @DCC Information Pane $timestamp $+ $chr(9) $+ $date $+ $chr(9) $+ $nick $+ $chr(9) $+ Get $+ $chr(9) $+ $nopath($filename) $+ $chr(9) $+ $getdir($nopath($filename)) $+ $chr(9) $+ $sizeround($lof($filename)) $+ $chr(9) $+ 3Yes $+ $chr(9) $+ 
  savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
}
ON *:FILESENT:*: {
  CreateWindow
  if ((: isin $filename) && ($left($filename,1) != \)) {
    %DCC.Send.Path = $nofile($filename)
    } | elseif ($left($filename,1) != \) {
    %DCC.Send.Path = $mircdir $+ $nofile($filename)
    } | else {
    %DCC.Send.Path = $left($mircdir,2) $+ $filename
  }
  aline -h @DCC Information Pane $timestamp $+ $chr(9) $+ $date $+ $chr(9) $+ $nick $+ $chr(9) $+ Send $+ $chr(9) $+ $nopath($filename) $+ $chr(9) $+ %DCC.Send.Path $+ $chr(9) $+ $sizeround($lof($filename)) $+ $chr(9) $+ 3Yes $+ $chr(9) $+ 
  savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
  unset %DCC.Send.Path
}
ON *:GETFAIL:*: {
  CreateWindow
  aline -h @DCC Information Pane $timestamp $+ $chr(9) $+ $date $+ $chr(9) $+ $nick $+ $chr(9) $+ Get $+ $chr(9) $+ $nopath($filename) $+ $chr(9) $+ $nofile($filename) $+ $chr(9) $+ $sizeround($lof($filename)) $+ $chr(9) $+ 4No $+ $chr(9) $+ 
  savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
}
ON *:SENDFAIL:*: {
  CreateWindow
  aline -h @DCC Information Pane $timestamp $+ $chr(9) $+ $date $+ $chr(9) $+ $nick $+ $chr(9) $+ Send $+ $chr(9) $+ $nopath($filename) $+ $chr(9) $+ $nopath($filename) $+ $chr(9) $+ $sizeround($lof($filename)) $+ $chr(9) $+ 4No $+ $chr(9) $+ 
  savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
}

ON 1:CLOSE:@DCC Information Pane: {
  ;  savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt 
}

alias ShowDCCList if ($window(@DCC Information Pane) == $Null) { CreateWindow } | window -ar @DCC Information Pane 

alias CreateWindow {
  ; Window Format:
  ; Timestamp Date Nick Action Filename Get-Dir Filesize Green/Red (coment)
  if ($window(@DCC Information Pane) == $null) { 
    window -nl -t8,15,25,30,55,70,77,82 @DCC Information Pane @DCC Information Pane 
    if ($exists( [ $dccinfodir $+ DCCLog.txt ] )) {
      loadbuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
    }
    else {
      aline @DCC Information Pane Time $+ $chr(9) $+ Date $+ $chr(9) $+ Nick $+ $chr(9) $+ Action $+ $chr(9) $+ Filename $+ $chr(9) $+ Location $+ $chr(9) $+ Size $+ $chr(9) $+ Succ? $+ $chr(9) $+ Commment
      ;   savebuf $active $dccinfodir [ $+ DCCLog.txt ]
    }
  }  
}
menu @DCC Information Pane  {
  dclick: {
    if ((*.wav iswm $gettok($sline($active,1),5,9)) || (*.mid iswm $gettok($sline($active,1),5,9)) || (*.mp3 iswm $gettok($sline($active,1),5,9))) {
      splay $gettok($sline($active,1),6,9) $+ $gettok($sline($active,1) ,5,9)
    }
    else {
      run $gettok($sline($active,1),6,9) $+ $gettok($sline($active,1) ,5,9)
    }
  }
  Run: {
    if ((*.wav iswm $gettok($sline($active,1),5,9)) || ($gettok(*.mid iswm $sline($active,1),5,9)) || (*.mp3 iswm $gettok($sline($active,1),5,9))) {
      splay $gettok($sline($active,1),6,9) $+ $gettok($sline($active,1) ,5,9)
    }
    else {
      run $gettok($sline($active,1),6,9) $+ $gettok($sline($active,1) ,5,9)
    }
  }
  Set Comment: {
    rline $active $sline($active,1).ln $gettok($sline($active,1),1-8,9) $+ $chr(9) $+ $$?="Comment?"
    savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
  }
  Delete from System: {
    if ($?!="Are you sure you want to delete this file?") {
      remove $gettok($sline($active,1),6,9) $+ $gettok($sline($active,1) ,5,9)
      dline $active $sline($active,1).ln
      savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
    }
  }    
  Delete from list: {
    dline $active $sline($active,1).ln
    savebuf @DCC Information Pane $dccinfodir $+ DCCLog.txt
  }    
  Send To: {
    dcc send $$?="Send to who?" $gettok($sline($active,1),6,9) $+ $gettok($sline($active,1) ,5,9)
  }
}  
alias -l sizeround {
  if ($$1 == $null) { return 0 Bytes }
  if ($$1 !isnum) { return $$1 }
  if ($$1 < 1024) {
    return $$1 Bytes
  } 
  elseif ($$1 < $calc(1024 ^ 2)) {
    return $round($calc($$1 / 1024),2) $+ Kb
  } 
  else {
    return $round($calc($$1 / (1024 ^ 2)),2) $+ Mb
  }
}

menu Channel,Status,Menubar {
  .-
  DCC Info List
  .Open Window: if ($window(@DCC Information Pane) == $Null) { CreateWindow } | window -ar @DCC Information Pane 
  .Reset Information: if ($?!="Are you sure you want to reset this information?") { remove $dccinfodir $+ DCCLog.txt }
}